When HTML, CSV, or XLS output is created by PROC MEANS or PROC SUMMARY with the PRINT option, the table that is displayed in Microsoft Excel will contain only one row. PROC MEANS/SUMMARY creates a stacked table, which cannot be displayed correctly by Microsoft Excel.

To circumvent the problem for the HTML and CSV destinations, create an output data set using the OUTPUT statement, transpose the output data set using PROC TRANSPOSE, and use PROC PRINT or PROC REPORT to display the transposed output. The sample code on the Full Code tab illustrates this.

Operating System and Release Information

/* Open the CSV, EXCELXP, and LISTING destinations                   */
ods csv file="csv.csv";
ods tagsets.excelxp file="excelxp.xls";
ods listing;

/* Add the NOPRINT option to prevent the default table from displaying */
proc means data=sashelp.class noprint;
   var age height;
/* Create an output data set without the variables _TYPE_ and _FREQ_ */
   output out=new(drop=_type_ _freq_);
run;

/* Transpose the output data set using the _STAT_ variable to name    */
/* the columns                                                        */
proc transpose data=new out=out;
   id _stat_;
run;

/* Print the data set with labels that match the output from the      */
/* default MEANS/SUMMARY table                                      */
proc print data=out l noobs;
   var _name_ n mean std min max ;
   label mean="Mean"
          std="Std Dev"
          min="Minimum"
          max="Maximum"
       _name_="Variable";
run;

/* Close all of the open destinations                                  */
ods _all_ close;
/* Reopen the LISTING destination                                      */
ods listing;